86 lines
2.8 KiB
Plaintext
86 lines
2.8 KiB
Plaintext
// Unity built-in shader source. Copyright (c) 2016 Unity Technologies. MIT license (see license.txt)
|
|
|
|
// August 2019
|
|
// Modified to have Hue changing ability using HSV values
|
|
// Compatible with standard Unity sprite renderer tint color
|
|
// Sam at Thousand Ant Studios
|
|
|
|
Shader "Sprites/Default-Hue"
|
|
{
|
|
Properties
|
|
{
|
|
[PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
|
|
[HideInInspector]
|
|
_Color ("Tint", Color) = (1,1,1,1)
|
|
[MaterialToggle] PixelSnap ("Pixel snap", Float) = 0
|
|
[HideInInspector] _RendererColor ("RendererColor", Color) = (1,1,1,1)
|
|
[HideInInspector] _Flip ("Flip", Vector) = (1,1,1,1)
|
|
[PerRendererData] _AlphaTex ("External Alpha", 2D) = "white" {}
|
|
[PerRendererData] _EnableExternalAlpha ("Enable External Alpha", Float) = 0
|
|
}
|
|
|
|
SubShader
|
|
{
|
|
Tags
|
|
{
|
|
"Queue"="Transparent"
|
|
"IgnoreProjector"="True"
|
|
"RenderType"="Transparent"
|
|
"PreviewType"="Plane"
|
|
"CanUseSpriteAtlas"="True"
|
|
}
|
|
|
|
Cull Off
|
|
Lighting Off
|
|
ZWrite Off
|
|
Blend One OneMinusSrcAlpha
|
|
|
|
Pass
|
|
{
|
|
CGPROGRAM
|
|
#pragma vertex SpriteVert
|
|
#pragma fragment SpriteFragHue
|
|
#pragma target 2.0
|
|
#pragma multi_compile_instancing
|
|
#pragma multi_compile _ PIXELSNAP_ON
|
|
#pragma multi_compile _ ETC1_EXTERNAL_ALPHA
|
|
#include "UnitySprites.cginc"
|
|
|
|
|
|
//adapted from: http://lolengine.net/blog/2013/07/27/rgb-to-hsv-in-glsl
|
|
float3 rgb2hsv(float3 c)
|
|
{
|
|
float4 K = float4(0.0, -1.0 / 3.0, 2.0 / 3.0, -1.0);
|
|
float4 p = lerp(float4(c.bg, K.wz), float4(c.gb, K.xy), step(c.b, c.g));
|
|
float4 q = lerp(float4(p.xyw, c.r), float4(c.r, p.yzx), step(p.x, c.r));
|
|
|
|
float d = q.x - min(q.w, q.y);
|
|
float e = 1.0e-10;
|
|
return float3(abs(q.z + (q.w - q.y) / (6.0 * d + e)), d / (q.x + e), q.x);
|
|
}
|
|
|
|
float3 hsv2rgb(float3 c)
|
|
{
|
|
float4 K = float4(1.0, 2.0 / 3.0, 1.0 / 3.0, 3.0);
|
|
float3 p = abs(frac(c.xxx + K.xyz) * 6.0 - K.www);
|
|
return c.z * lerp(K.xxx, saturate(p - K.xxx), c.y);
|
|
}
|
|
|
|
fixed4 SpriteFragHue(v2f IN) : SV_Target
|
|
{
|
|
fixed4 c = SampleSpriteTexture (IN.texcoord);
|
|
float3 c_hsv = rgb2hsv(c.rgb);
|
|
float3 hueShift = rgb2hsv(IN.color.rgb);
|
|
c_hsv.x = frac(c_hsv.x + hueShift.x);
|
|
float3 shifted = hsv2rgb(c_hsv);
|
|
c.rgb = lerp(c.rgb, shifted.rgb, hueShift.y);
|
|
c.rgb *= hueShift.z;
|
|
c.rgb *= c.a;
|
|
return c;
|
|
}
|
|
|
|
ENDCG
|
|
}
|
|
}
|
|
}
|